 Re: Webラジオの保存方法の質問はこちら【22】 ( No.101 ) |
- 日時： 2016/07/07 00:52
- 名前： おひげ
- >>99 ガニさん
若干謎が残りましたがとりあえず問題が解決したようで安心しました。
最近楽屋裏ラジオも増えてきたようで、URLコピーしてコマンドを編集したり実行するのが面倒かも
しれないので前に作ったアニメイト用のバッチファイルをちょっと弄って響用に変更してみました。
XP環境を使用している場合は、TIMEOUTコマンドが使用できないのでPauseなどに置き換えてください。
単純にURLとファイル名をコマンドに当てはめて実行するだけのバッチなのでURL等のチェック機能はありません。
-------ここから下をコピペして 適当な名前で保存して拡張子を .bat に変更してください-------(この行は含めないこと)
@echo off
:: ←この行はコメントです 【 ":" 1文字はジャンプ用のラベル "::" 2文字は注釈用のコメントになります】
echo.
echo **** 響 -HiBiKi Radio Station- 楽屋裏ダウンロード補助 (携帯ページ用) ****
echo.
echo 取得したURLをダウンロードコマンドに投げて実行するだけのバッチファイルです
echo.
echo 事前に響のWEBサイトにて楽屋裏ラジオのURLを取得しておく必要があります
echo 同一フォルダに ffmpeg.exe が無いと正常に動作しません
echo.
title 響 -HiBiKi Radio Station- 楽屋裏ダウンロード補助
:Check
:: ffmpeg.exe が同一フォルダにあるかどうかチェック
IF EXIST ffmpeg.exe (GOTO URL_IN)
echo.
echo ffmpeg.exe が同一フォルダに見つかりませんでした
echo パスが切られている場所に ffmpeg.exeが 無い場合、ダウンロードは行われません
echo.
pause
goto END
:URL_IN
:: URL入力用VBS作成処理
echo With CreateObject("Scripting.FileSystemObject").CreateTextFile("URL.txt") >>URL.VBS
echo .WriteLine InputBox("モバイル向けページのURL(.m3u8)を入力します","響 -HiBiKi Radio Station-","楽屋裏を再生して検出されたURLを入力してください") >>URL.VBS
echo .Close >>URL.VBS
echo End With >>URL.VBS
:: URL入力用VBSを実行してURLを環境変数にセットして作業ファイル削除
URL.VBS
set /p URL= < URL.txt
del url.vbs >nul
del url.txt >nul
:: 入力したURLをチェック？ 何もいれないでOKを押したり、キャンセルをした場合再実行
if "%URL%" NEQ "楽屋裏を再生して検出されたURLを入力してください" (goto FILE_IN)
goto URL_IN
:FILE_IN
:: ラジオ名入力用VBS作成処理
echo With CreateObject("Scripting.FileSystemObject").CreateTextFile("NAME.txt") >>NAME.VBS
echo .WriteLine InputBox("ラジオのファイル名を入力します","響 -HiBiKi Radio Station-","ラジオの名称を入れてください") >>NAME.VBS
echo .Close >>NAME.VBS
echo End With >>NAME.VBS
:: ラジオ名入力用VBSを実行して名前を環境変数にセットして作業ファイル削除
NAME.VBS
set /p NAME= < NAME.txt
del NAME.vbs >nul
del NAME.txt >nul
:: 入力した名称チェック
if "%NAME%" NEQ "ラジオの名称を入れてください" (goto download)
set NAME=Radio
:download
echo.
echo **** ダウンロード処理を行います ****
echo.
echo ソースURL : "%URL%"
echo 出力ファイル : "%NAME%.mp4"
echo.
echo Codec for stream 0 does not use global headers の警告は映像データが無い動画
echo を保存しようとした場合に出る警告です
echo.
echo Invalid data found when processing input 等のエラーが表示されている場合は、
echo URLの取得から時間が経過しすぎた場合や入力したURLに不備があるものと思われます
echo.
:: XP環境の場合 timeout 2 を pause に変更してください
timeout 2 >nul
ffmpeg -stats -i "%URL%" -loglevel warning -vcodec copy -acodec copy -bsf:a aac_adtstoasc "%NAME%.mp4"
echo.
echo *** ダウンロード処理は終了しました ***
echo.
echo 正常に完了している場合は、フォルダに %NAME%.mp4 が作成されています
echo 再生して確認をお願いします
echo.
goto END
:END
:: XP環境の場合 timeout 15 を pause に変更してください
timeout 15
exit
-------ここから上をコピペしてください-------(この行は含めないこと)
|
|