 Re: Webラジオの保存方法の質問はこちら【24】 ( No.48 ) |
- 日時： 2017/07/20 22:38
- 名前： おひげ
- >>47 にこさん
試してみましたが、ニコニコの保存はCravingの現行バージョン (1.8.5(2017/06/23))で
問題なく保存できるようです。
最新と思われる #40 (sm31599472)も問題なく保存できました。
まあ、大元は超A&G+のようなのでそちらを保存した方がはやいのかもしれませんが...
念のために超A&G+を保存するバッチを記載しておきます。
同一フォルダに rtmpdump.exe を置いた状態でラジオ放送時間に起動し、ラジオ名称と
録画時間(分)を入力すればその時間の間記録を行います。
放送時間前に起動して終了時間が収まるような記録時間を入力すれば保存されます。
(保存後、FLVから音声を取り出して余計なCM部分をカットすればOKです)
-------ここから下をコピペしてください-------(この行は含めないこと)
@echo off
title 文化放送 超！Ａ＆Ｇ＋記録
setlocal
:: 超Ａ＆Ｇ＋鯖番号 (aandg11で記録できない場合は下記をaandg22などに変更して確認ください)
set server=aandg11
:Check
:: ffmpeg.exe が同一フォルダにあるかどうかチェック
IF EXIST rtmpdump.exe (GOTO MESS)
echo.
echo rtmpdump.exe が同一フォルダに見つかりませんでした。
echo パスが切られている場所に rtmpdump.exe が 無い場合、記録は行われません。
echo.
pause
echo.
:MESS
cls
echo ***************************************************************************
echo 超Ａ＆Ｇ＋ (http://www.agqr.jp/) を記録するバッチファイルです
echo ラジオ名(記録ファイル名)と時間(分)を入力することで指定時間録画します
echo ***************************************************************************
echo.
echo ラジオ名を入力してください。(未入力のままOKを押すと名称はRadioとなります)
:INPUT
:FILE_IN
:: ラジオ名入力用VBS作成処理
echo With CreateObject("Scripting.FileSystemObject").CreateTextFile("NAME.txt") >>NAME.VBS
echo .WriteLine InputBox("ラジオのファイル名を入力します","超A&G+ 保存補助","ラジオの名称を入れてください") >>NAME.VBS
echo .Close >>NAME.VBS
echo End With >>NAME.VBS
:: ラジオ名入力用VBSを実行して名前を環境変数にセットして作業ファイル削除
NAME.VBS
set /p title= < NAME.txt
del NAME.vbs >nul
del NAME.txt >nul
:: 入力した名称チェック
if "%title%" NEQ "ラジオの名称を入れてください" (goto MESS2)
set title=Radio
:MESS2
echo.
echo 記録時間を入力してください。(半角数字で入力します)
echo.
echo 保存をキャンセルしたい場合は先にこのウィンドウを閉じてから入力ボックスを閉じてください。
:SEC_IN
:: 記録時間入力用VBS作成処理
echo With CreateObject("Scripting.FileSystemObject").CreateTextFile("NAME.txt") >>NAME.VBS
echo .WriteLine InputBox("記録時間[分]を半角数字で入力します","超A&G+ 保存補助","記録する時間[分]を半角数字で入力入れてください") >>NAME.VBS
echo .Close >>NAME.VBS
echo End With >>NAME.VBS
:: ラジオ名入力用VBSを実行して名前を環境変数にセットして作業ファイル削除
NAME.VBS
set /p sec= < NAME.txt
del NAME.vbs >nul
del NAME.txt >nul
:: 入力した名称チェック
if "%sec%" NEQ "記録する時間[分]を半角数字で入力入れてください" (goto INIT)
goto SEC_IN
:INIT
set dur=
set /a dur = 60 * %sec%
:: 実行因数設定 (タイトル,実行時間,実行長さを処理)
set time2=%time: =0%
set ymd=[%date:~-10,4%%date:~-5,2%%date:~-2,2%]-%time2:~0,2%%time2:~3,2%%time2:~6,2%
set out="%title%%ymd%.flv"
set rtmp=rtmpdump.exe
set /A count=0
set maxct=200
:: 録音処理部
cls
echo ***************************************************************************
echo 超Ａ＆Ｇ＋ 録音実行中 番組名 : (%title%)
echo.
echo 開始日 : %ymd% 録音時間 : %sec%分(%dur%秒)
echo.
echo [%out%]
echo ***************************************************************************
echo.
echo 途中で保存を中断したい場合はこのウィンドウを閉じてください。
echo.
:REC
set /A count+=1
IF %count% == %maxct% goto END
%rtmp% --rtmp "rtmpe://fms2.uniqueradio.jp/" --playpath "%server%" --app "?rtmp://fms-base1.mitene.ad.jp/agqr/" --stop %dur% --live -o %out%
FOR %%I IN (%out%) DO IF %%~zI==0 goto REC
:END
endlocal
-------ここから上をコピペしてください-------(この行は含めないこと)
バッチファイルをちょっと変更して応答部分を無くしてラジオ名や保存時間を引数に変更し、ウィンドウズのスケジューラに
組込めば毎週指定時間に起動して保存なども可能です。
|
|