 Re: Webラジオの保存方法の質問はこちら【22】 ( No.35 ) |
- 日時： 2016/03/18 01:28
- 名前： おひげ
- >>28
>>33
飃さん、りんりんさん情報ありがとうございます。
とりあえずざっくりですが携帯用のページからのダウンロード(品質選択のみ)を作ってみました。
全部DOS画面でやってもよかったのですが、なんとなく味気ないので一部VBSを使っています。
環境によってはうまく動かないかもしれませんが特別なことはしてないのでたぶん大丈夫かな？
(XP環境の場合は 最終行付近の "timeout 15" を "pause" に変更してください)
スマホ用の配信ページのURLの取得方法などは >>33 のりんりんさんの書き込みを参照ください。
同一フォルダに ffmpeg.exe を置いた状態で実行して下さい。
※URLのチェックは未入力の場合(デフォルト文字だった場合)のみをチェックしています。
※ラジオ名称は未入力の場合は Radio(選択した品質).mp4 になります。
※ストリームが複数ないラジオ(映像が真っ暗な物)の場合、高品質や低品質を選択するとエラーになります。
※品質選択はDOS画面になります。VBSでやると行数が多くなりすぎたので...
ゆうきとつばさのひよこ 第380回で比較した場合
標準 :29.2MB 映像 320x240 220kbps 音声 64kbps
高品質:35.0MB 映像 320x240 290kbps 音声 64kbps
低品質:16.8MB 映像 320x240 100kbps 音声 64kbps
になっていました。
-------ここから下をコピペして 適当な名前で保存して拡張子を .bat に変更してください-------(この行は含めないこと)
@echo off
:: ←この行はコメントです 【 ":" 1文字はジャンプ用のラベル "::" 2文字は注釈用のコメントになります。】
echo.
echo ************ アニメイトTV WEBラジオダウンロード (携帯ページ用) ************
echo.
title アニメイトTV WEBラジオダウンロード (携帯ページ用)
:Check
:: ffmpeg.exe が同一フォルダにあるかどうかチェック
IF EXIST ffmpeg.exe (GOTO URL_IN)
echo.
echo ffmpeg.exe が同一フォルダに見つかりませんでした。
echo パスが切られている場所に ffmpeg.exeが 無い場合、ダウンロードは行われません。
echo.
pause
goto END
:URL_IN
:: URL入力用VBS作成処理
echo With CreateObject("Scripting.FileSystemObject").CreateTextFile("URL.txt") >>URL.VBS
echo .WriteLine InputBox("モバイル向けページのURLを入力します","アニメイトWEBラジオ","再生ボタンのURLを入力してください") >>URL.VBS
echo .Close >>URL.VBS
echo End With >>URL.VBS
:: URL入力用VBSを実行してURLを環境変数にセットして作業ファイル削除
URL.VBS
set /p URL= < URL.txt
del url.vbs >nul
del url.txt >nul
:: 入力したURLをチェック？ 何もいれないでOKを押したり、キャンセルをした場合再実行
if "%URL%" NEQ "再生ボタンのURLを入力してください" (goto FILE_IN)
goto URL_IN
:FILE_IN
:: ラジオ名入力用VBS作成処理
echo With CreateObject("Scripting.FileSystemObject").CreateTextFile("NAME.txt") >>NAME.VBS
echo .WriteLine InputBox("ラジオのファイル名を入力します","アニメイトWEBラジオ","ラジオの名称を入れてください") >>NAME.VBS
echo .Close >>NAME.VBS
echo End With >>NAME.VBS
:: ラジオ名入力用VBSを実行して名前を環境変数にセットして作業ファイル削除
NAME.VBS
set /p NAME= < NAME.txt
del NAME.vbs >nul
del NAME.txt >nul
:: 入力した名称チェック
if "%NAME%" NEQ "ラジオの名称を入れてください" (goto SELECT)
set NAME=Radio
:SELECT
:: ダウンロード形式選択
title %NAME% ダウンロード
echo ************ ダウンロード形式の選択 ************
echo [1] : 標準 (ストリーム 0,1 保存)
echo [2] : 高品質 (ストリーム 2,3 保存)
echo [3] : 低品質 (ストリーム 4,5 保存)
echo ************************************************
echo.
echo よくわからない場合は "1" を選択してください
echo.
set /p NUM="ダウンロードしたい品質を選択してください >"
if "%NUM%"=="1" goto Nomal
if "%NUM%"=="2" goto High
if "%NUM%"=="3" goto Low
:Nomal
:: 標準品質 (ストリーム 0,1 保存)
ffmpeg -stats -i "%URL%" -vcodec copy -acodec copy -bsf:a aac_adtstoasc "%NAME%(標準).mp4"
goto END
:High
:: 高品質 (ストリーム 2,3 保存)
ffmpeg -stats -i "%URL%" -map 0:2 -map 0:3 -vcodec copy -acodec copy -bsf:a aac_adtstoasc "%NAME%(高品質).mp4"
goto END
:Low
:: 低品質 (ストリーム 4,5 保存)
ffmpeg -stats -i "%URL%" -map 0:4 -map 0:5 -vcodec copy -acodec copy -bsf:a aac_adtstoasc "%NAME%(低品質).mp4"
goto END
:END
:: XP環境の場合 timeout 15 を pause に変更してください
timeout 15
exit
-------ここから上をコピペしてください-------(この行は含めないこと)
|
|